mirror of
https://github.com/coder/coder.git
synced 2025-07-12 00:14:10 +00:00
f7ea016494
* Pass workspace owner email address to provisioner * Remove owner_email and owner_username fields from agent metadata * Add Git environment variables to example templates * Remove "owner_name" field from provisioner metadata, use username instead * Remove Git configuration from most templates, add documentation * Proofreading/typo fixes from @mafredri * Update example templates to latest version of terraform-provider-coder
91 lines
2.2 KiB
HCL
91 lines
2.2 KiB
HCL
terraform {
|
|
required_providers {
|
|
coder = {
|
|
source = "coder/coder"
|
|
version = "0.4.3"
|
|
}
|
|
google = {
|
|
source = "hashicorp/google"
|
|
version = "~> 4.15"
|
|
}
|
|
}
|
|
}
|
|
|
|
variable "project_id" {
|
|
description = "Which Google Compute Project should your workspace live in?"
|
|
}
|
|
|
|
variable "zone" {
|
|
description = "What region should your workspace live in?"
|
|
default = "us-central1-a"
|
|
validation {
|
|
condition = contains(["northamerica-northeast1-a", "us-central1-a", "us-west2-c", "europe-west4-b", "southamerica-east1-a"], var.zone)
|
|
error_message = "Invalid zone!"
|
|
}
|
|
}
|
|
|
|
provider "google" {
|
|
zone = var.zone
|
|
project = var.project_id
|
|
}
|
|
|
|
data "google_compute_default_service_account" "default" {
|
|
}
|
|
|
|
data "coder_workspace" "me" {
|
|
}
|
|
|
|
resource "google_compute_disk" "root" {
|
|
name = "coder-${lower(data.coder_workspace.me.owner)}-${lower(data.coder_workspace.me.name)}-root"
|
|
type = "pd-ssd"
|
|
zone = var.zone
|
|
image = "debian-cloud/debian-9"
|
|
lifecycle {
|
|
ignore_changes = [image]
|
|
}
|
|
}
|
|
|
|
resource "coder_agent" "dev" {
|
|
auth = "google-instance-identity"
|
|
arch = "amd64"
|
|
os = "linux"
|
|
}
|
|
|
|
resource "google_compute_instance" "dev" {
|
|
zone = var.zone
|
|
count = data.coder_workspace.me.start_count
|
|
name = "coder-${lower(data.coder_workspace.me.owner)}-${lower(data.coder_workspace.me.name)}-root"
|
|
machine_type = "e2-medium"
|
|
network_interface {
|
|
network = "default"
|
|
access_config {
|
|
// Ephemeral public IP
|
|
}
|
|
}
|
|
boot_disk {
|
|
auto_delete = false
|
|
source = google_compute_disk.root.name
|
|
}
|
|
service_account {
|
|
email = data.google_compute_default_service_account.default.email
|
|
scopes = ["cloud-platform"]
|
|
}
|
|
# The startup script runs as root with no $HOME environment set up, which can break workspace applications, so
|
|
# instead of directly running the agent init script, setup the home directory, write the init script, and then execute
|
|
# it.
|
|
metadata_startup_script = <<EOMETA
|
|
#!/usr/bin/env sh
|
|
set -eux pipefail
|
|
|
|
mkdir /root || true
|
|
cat <<'EOCODER' > /root/coder_agent.sh
|
|
${coder_agent.dev.init_script}
|
|
EOCODER
|
|
chmod +x /root/coder_agent.sh
|
|
|
|
export HOME=/root
|
|
/root/coder_agent.sh
|
|
|
|
EOMETA
|
|
}
|